# Cifrar y descifrar conexiones
Los datos de cada conexión de `connections.xml` (servidor, usuario, contraseña) pueden ir **en claro** dentro de `XmlSettings` o **cifrados y codificados en base 64**. Cifrarlos evita que la contraseña quede legible a simple vista cuando alguien abre el archivo, revisa un respaldo o comparte una captura. Esta página explica cómo hacerlo en 2.0, en Linux y en Windows, desde DKL.
## Cómo se ve cada forma
En claro, dentro de un bloque CDATA:
```xml
MY_SQL
127.0.0.1
mi_usuario
MiClave#2026
erp
3306
]]>
```
Cifrada:
```xml
2tT8fZqUoZMO1rY1haYX9giCm6f7HXLigQzMu4Pi+MnSSJPZUBYAU3Xlb56v2U+30X3Tk2lk…
```
Devkron distingue las dos solas: si el contenido trae `Engine`, lo toma en claro; si no, lo descifra. Puede mezclar conexiones cifradas y en claro en el mismo archivo. El cifrado de 2.0 es el mismo de 1.x: un `connections.xml` cifrado con 1.x funciona en 2.0 y al revés.
## Crear una conexión ya cifrada
`dba.createconnection` de `dbr.dkh` siempre guarda la conexión **cifrada**. Es la forma recomendada de dar de alta conexiones en un servidor:
```dkl
#include "dkli.dkh"
#!
program "alta-conexion"
{
#include "functions.dkh"
#include "dbr.dkh"
new datos
{
@"Engine": "MY_SQL"
@"Host": "127.0.0.1"
@"UserName": "mi_usuario"
@"Password": "MiClave#2026"
@"DefaultSchema": "erp"
@"Port": "3306"
@"SSLMode": "2"
@"Parameters": "AllowPublicKeyRetrieval=true"
}
if dba.cnnexists("ventas@miapp") { do dba.delconnection("ventas@miapp") }
else { do dba.addapp("miapp") }
do dba.createconnection("ventas@miapp", datos, @true, "")
do print("Conexión guardada (cifrada) en connections.xml")
}
```
```text
Conexión guardada (cifrada) en connections.xml
```
Ejecútelo desde la carpeta donde está (o va a estar) `connections.xml` y con un usuario que pueda escribirlo; después **borre el programa**, porque contiene la contraseña. El tercer argumento (`@true`) marca la conexión como predeterminada del grupo.
## Cifrar una conexión que está en claro
Este programa lee la conexión, la borra y la vuelve a guardar cifrada:
```dkl
#include "dkli.dkh"
#!
program "cifrar-conexion"
{
#include "functions.dkh"
#include "dbr.dkh"
// Uso: dkl cifrar.dkl -cnn:ventas@miapp
ref args = commandline(":")
qname = field.dstr(args, "-cnn", "")
if qname == "" { do rise_error(0, "Indique la conexión con -cnn:conexion@aplicacion") }
ref info = dba.getconnection(qname)
if isnull(info) { do rise_error(0, "No existe la conexión " + qname) }
do dba.delconnection(qname)
do dba.createconnection(qname, info, @true, "")
do print("Conexión " + qname + " guardada cifrada")
}
```
```bash
cd /opt/devkron
sudo -u devkron ./dkl /opt/herramientas/cifrar.dkl -hide-log -cnn:ventas@miapp
```
```text
Conexión ventas@miapp guardada cifrada
```
**Antes de usarlo, revise dos cosas:**
- `dba.getconnection` devuelve solo los datos que el adaptador conoce: en MySQL **no devuelve ``**, y en SQL Server solo `Host`, `UserName`, `Password`, `DefaultSchema` y `WindowsAuthMode`. Si la conexión usa `` (por ejemplo `AllowPublicKeyRetrieval=true` o `ConvertZeroDateTime=true`), agréguelo al registro antes de guardar: `info<"Parameters">: "AllowPublicKeyRetrieval=true"`, o dé de alta la conexión completa como en la sección anterior.
- El programa marca la conexión como predeterminada (`@true`) y no conserva el `SQLDic`; cambie esos argumentos si su conexión los necesita distintos.
Haga una copia de `connections.xml` antes de cifrar.
## Ver los datos de una conexión cifrada
```dkl
#include "dkli.dkh"
#!
program "ver-conexion"
{
#include "functions.dkh"
#include "serialize.dkh"
#include "dbr.dkh"
// Uso: dkl descifrar.dkl -cnn:ventas@miapp
ref args = commandline(":")
ref info = dba.getconnection(field.dstr(args, "-cnn", ""))
info<"Password">: "********"
do print(to.json(info))
}
```
```text
{"Host":"127.0.0.1","UserName":"mi_usuario","Password":"********","DefaultSchema":"docintro","Port":"3307","SSLMode":"0","Engine":"MY_SQL"}
```
El ejemplo oculta la contraseña a propósito; si necesita verla para un diagnóstico, quite esa línea y no deje la salida en bitácoras ni la comparta.
## La utilidad `showcnninfo.exe`
Para Windows existe la utilidad `showcnninfo.exe`, que cifra y descifra el contenido de `XmlSettings` desde una ventana:
| Archivo | Descripción |
|---|---|
| [showcnninfo.exe](https://assets.induxsoft.net/sites/3p/herramientas/showcnninfo.exe) | utilidad de cifrado y descifrado (Windows) |
| [connections.xml](https://assets.induxsoft.net/sites/3p/herramientas/connections.xml) | archivo de ejemplo para probar la utilidad |
1. Abra `showcnninfo.exe`.
2. Para cifrar, escriba o pegue la información de conexión en claro (el bloque `…`) y pulse **Encriptar**. Copie el resultado dentro del elemento `XmlSettings` de la conexión.
3. Para revisar una conexión cifrada, pegue el contenido cifrado y pulse **Desencriptar**.
Como el cifrado de 2.0 es el mismo de 1.x, lo que produce la utilidad funciona en 2.0. En Linux, use los programas DKL de arriba.
## Recomendaciones
- El cifrado de `connections.xml` evita que las contraseñas queden legibles a simple vista, pero **no sustituye la protección del archivo**: quien tenga el archivo y Devkron (o la utilidad) puede descifrarlo. Proteja `connections.xml` con permisos del sistema (lectura solo para el usuario del servicio, por ejemplo `640` con dueño `root` y grupo `devkron`) y nunca lo ponga en una carpeta publicada por la web.
- No comparta capturas de pantalla ni archivos con datos de conexión reales.
- Use en la base de datos un usuario con los permisos mínimos que necesita la aplicación.