# Contexto declarativo e imperativo
El **contexto** decide cómo se procesa cada elemento del árbol:
- **Declarativo**: el elemento se traduce a XML tal como se escribió.
- **Imperativo**: el elemento es una sentencia (asignación, llamada, ciclo…) que se ejecuta.
Un archivo empieza en contexto declarativo. Las directivas de contexto cambian el modo de las líneas que siguen:
| Directiva | Efecto |
|---|---|
| `#!` | Pasa a imperativo. Si ya lo está, no hace nada. |
| `#$` | Pasa a declarativo. Si ya lo está, no hace nada. |
| `##` | Conmuta: de declarativo a imperativo y viceversa. |
`#$` también puede ir pegado a un elemento: `#$li(n="1"){ … }` declara ese elemento en modo declarativo y deja el modo así para lo que sigue.
## Generar HTML desde un ciclo
El caso más común: una tabla HTML a partir de datos.
```dkl
#include "dkli.dkh"
#!
program "tabla"
{
#include "functions.dkh"
#include "serialize.dkh"
ref productos = from.json("[{\"n\":\"Lápiz\",\"p\":5.5},{\"n\":\"Goma\",\"p\":3}]")
#$
table
{
#!
for i = 0; i < list.count(productos)
{
ref r = list.obj(productos, i)
#$
tr
{
td{ "#<@@(r, \"n\")>" }
td(align="right"){ $"#<@@(r, \"#p\") : #,#.00>" }
}
#!
}
#$
}
}
```
```text
```
El patrón es siempre el mismo: `#$` antes de lo que se imprime y `#!` antes de lo que se ejecuta. Cada cambio vale hasta el siguiente.
## Conmutar con ##
```dkl
#include "dkli.dkh"
raiz
{
##
a = 2
##
valor(a="#"){}
##
if a == 2
{
##
si{}
##
}
else
{
##
no{}
##
}
##
}
```
```text
```
`##` es cómodo para insertar una o dos líneas de código en un documento declarativo; para bloques largos, `#!` y `#$` son más fáciles de leer porque dicen a qué modo se va.
## Imprimir y producir XML en el mismo programa
`print` escribe en la consola en el momento; el árbol XML se escribe al terminar el programa. Por eso las líneas de `print` salen antes:
```dkl
#include "dkli.dkh"
#!
program "mezcla"
{
#include "functions.dkh"
do print("línea impresa")
#$
salida(x="1"){ $"cuerpo" }
#!
do print("otra línea")
}
```
```text
línea impresa
otra línea
cuerpo
```
En un servidor web, el árbol es la respuesta HTML; `print` va a la bitácora del servidor, no al navegador.
## Errores típicos
- **Una sentencia en modo declarativo** se imprime como XML (``) en vez de ejecutarse. Revise que haya un `#!` antes.
- **Un elemento en modo imperativo** (`div{}` después de `#!`) da `Sentencia no válida o declaración de elemento en contexto de interpretación`.
- **Un `#include` de código** se analiza en modo declarativo: el archivo incluido debe empezar con `#!`. Vea [Directivas](/es/devkron/2.0/lenguaje/declarativo/directivas.md).
- La sentencia **`include` (sin `#`) en modo declarativo** no se ejecuta: aparece en la salida como ``. Póngala después de `#!`.
- Un **bloque `$$ … $$`** (2.0) solo se permite en contexto imperativo, dentro de `new`/`using`/`member`.